C i b o M a h t o . c o m

Some time ago, I picked up an LCD photo frame that was on clearance, however it’s screen quality turned out to be quite unsuitable for actually showing photos. I wasn’t sure what to do with it, but I thought it would be a shame to waste the thing, so I decided to turn it into a ridiculous clock.

The idea is pretty straightforward, I just built a circuit to hit the ‘next’ button every minute, then generated 720 photos to store on it, one for each minute in a 12-hour cycle. I chose to write out the time in words, however really anything could be used and displayed. Build instructions after the break.

Building the clock

To build the clock, you will need an extra LCD photo frame, an Arduino microcontroller (the Bare Bones Board Arduino clone is shown here, but I ended up using a Really Bare Bones Board), a 4N25 optocoupler, a 100 ohm (or so) resistor, and some wire. Optionally, you can also make a new frame for your clock using some matting.

1. Wire a microcontroller to the clock
To make the clock advance every minute, I wired up an RBBB Arduino clone to the forward button, and programmed it to press the button every minute. I used a 4N25 optocoupler to simulate button presses. Here is the schematic:

And this is what it looks like, installed (new parts highlighted):

2. Program the micro to trigger the optocoupler every minute
Here is the Arduino sketch that I am using:

#define forwardButton 12
 
// Initialize the IO ports
void setup()
{
  pinMode(forwardButton, OUTPUT);
  digitalWrite(forwardButton, LOW);
} 
 
// Main loop
void loop()
{
  unsigned long startTime = millis();
  unsigned long temp;
 
  // Pretend to be a regular clock, and tick once a second.
  while (true)
  {
    startTime += 60000; // 60000 milliseconds per minute
 
    // Advance the time
    digitalWrite(forwardButton, HIGH);
    delay(300);
    digitalWrite(forwardButton, LOW);
 
    // Wait until a minute has passed.  Note that this will do ugly things when millis()
    // runs over, so it might get messed up after 50 days- check back here for an update!
    while (startTime - millis() > 0) {};
  }
}

3. Generate a set of pictures to represent the time
After the circuit is set up, we have an LCD photo frame that advances to the next picture every minute. To turn it into a clock, we have to generate an image to represent each minute. It could be fun to make one that has a different photo background every minute, that shows a really slow animation, or that slowly fades between colors- the choice is up to you.

For mine, I decided to keep it simple and make one that shows the words written out in English. I played around with slightly different picture sizes, colors and fonts until I found something that looked good on the LCD:

There are couple things to note here. First, the colors look really ugly on the computer screen, but the photo frame interprets this as a pleasing shade of green. Second, my photo frame insists on displaying an indicator graphic every time the forward button is pressed, so to get around this, I just put electrical tape over that part of the screen and then made a matte frame to cover the tape.

Once I had an image that I liked, I made a Processing script to generate a picture for each minute:

// Set these to match the resolution of your clock
int imageWidth = 480;
int imageHeight = 260;
 
// Adjust these until the display looks right
int textSize = 45; 
int textStartX = 30;
int textStartY = 220;
 
String[] onesStrings =
  { "twelve", "one", "two", "three", "four", "five",
    "six", "seven", "eight", "nine", "ten",
    "eleven", "twelve", "thirteen", "fourteen", "fifteen",
    "sixteen", "seventeen", "eighteen", "nineteen" };
 
String[] tensStrings =
  { "twenty", "thirty", "forty", "fifty" };
 
PFont myFont;
 
// Print the specified time onto the screen
void drawTime(int hours, int minutes) {
 
  // First, add the hour
  String timeString = onesStrings[hours%12] + " ";
 
  // Then, build the minutes
  if( minutes == 0 ) {
    // 0 minutes means it's right on the hour.
    timeString += "o'clock";
  }
  else if( minutes < 10 ) {
    // 0 - 9
    timeString += "oh " + onesStrings[minutes];
  }
  else if( minutes < 20 ) {
    //  teens
    timeString += onesStrings[minutes];
  }
  else {
    // first find the 10's digit
    timeString += tensStrings[minutes/10 - 2];
 
    // then add a 1's digit if applicable
    if( minutes%10 > 0 ) {
      timeString += "-" + onesStrings[minutes%10];
    }
  }
 
  // Write the time out to the screen at the specified coordinates
  text( timeString, textStartX, textStartY); 
}
 
void setup() {
  // Set the screen to the size of our LCD, so that it doesn't have to resize the image
  size(imageWidth, imageHeight);
 
  // I use Comic Sans because it looks best.
  myFont = createFont("Comic.TTF", textSize);
  textFont(myFont);
 
  // Set the drawing to black
  stroke(0);
  fill(0);
 
  // Keep a count of how many images have been generated, to use to generate unique
  // files names.
  int count = 0;
 
  // Create an image for every minute of every hour.
  for( int hours = 0; hours < 12; hours++ ) {
    for( int minutes = 0; minutes < 60; minutes++) {
      // Clear the background by painting over it
      background(230, 184, 0);
 
      // Draw text for the current time cycle
      drawTime(hours, minutes);
 
      // Write out an image file.  The filesystem on my SD card wouldn't allow
      // more than a few hundred images in a single directory, so I break them
      // up into groups of 200.
      save(count/200 + "/" + count++ + ".jpg");
    }
  }
}

4. Load the picture into the photo frame
My frame reads photos from an SD card, so I loaded one up and stuck it into the frame. One issue I ran into is that the FAT filesystem that my card was formatted with didn’t like having 720 photos in a single directory, so I broke them up into groups of 200 (the script above does this automatically). Once everything is loaded, the clock should be good to go. To set it, press the forward button a bunch of times until you get to the right time (it is tedious).

5. Enjoy!
Set the clock on an endtable, hang it to the wall, or give it out as a gift!

Possible improvements:

• Add second optocoupler, to automatically press the ‘pause’ button when the frame starts up
• Do something more interesting with the graphics display (photos? changing colors? human clock?)
• Add an ambient light sensor, and use it to control the brightness of the LCD backlight.